' *****************************************************************************************
'								FUNCIONES DE UTILIDAD (vbscript)
'
'		- Funciones para cálculo de fechas
'				sCalcularFecha(sFecha, sDias)
'				sFechaModificacionFichero(sRuta)
'				sFechaLarga(sFecha, bDenDiaSemana)
'				sDiaSemana(sFecha)
'
' *****************************************************************************************

'--------------------------------------------------------------------------
' Nombre: sCalcularFecha
' Descripción: función que incrementa/decrementa una fecha según unos días
' Fecha: 18/10/2004
' Autor: Departamento de Desarrollo - Tecnología (JPP)
' Parámetros:
'		sFecha -> fecha 
'		sDias -> los días que se quieren incrementar/decrementar
'--------------------------------------------------------------------------
Function sCalcularFecha(sFecha, sDias)

	If sFecha <> "" Then
		sCalcularFecha = CStr(FormatDateTime(DateAdd("D", CInt(sDias), sFecha), vbShortDate))
	Else
		sCalcularFecha = ""
	End If

End Function

'--------------------------------------------------------------------------
' Nombre: sFechaModificacionFichero
' Descripción: función que obtiene la fecha/hora de modificación de un fichero
' Fecha: 11/05/2005
' Autor: Departamento de Desarrollo - Tecnología (JAR)
' Parámetros:
'		sRuta -> Ruta absoluta del fichero a consultar 
'--------------------------------------------------------------------------
Function sFechaModificacionFichero(sRuta)

	Dim oFSO
	dim oFichero
	
	Set oFSO = CreateObject("Scripting.FileSystemObject")
	
	' Comprobar que existe el fichero
	if (not oFSO.FileExists(sRuta)) Then
		MsgBox "El fichero no existe"
		sFechaModificacionFichero = ""
	Else
		Set oFichero = oFSO.GetFile(sRuta)
		sFechaModificacionFichero = cstr(oFichero.DateLastModified)
		'sFechaModificacionFichero = oFichero.DateCreated
		'sFechaModificacionFichero = oFichero.DateLastAccessed
		Set oFichero = Nothing
	End If
	
	Set oFSO = Nothing
	
End Function


'------------------------------------------------------------------------------------
' Nombre: sFechaLarga
' Descripción: convierte una fecha al formato largo
' Fecha: 26/05/2005
' Autor: Departamento de Desarrollo - Tecnología (JPP)
' Parámetros: 
'			sFecha -> fecha 
'			bDenDiaSemana -> booleano que indica si se quiere que devuelva también la
'							 denominación del día de la semana
' Retorno: fecha en formato largo (opcional la denominación del día de la semana)
'------------------------------------------------------------------------------------
Function sFechaLarga(sFecha, bDenDiaSemana)

	Dim sFechaL

	sFechaL = ""
	If bDenDiaSemana Then
		sFechaL = sDiaSemana(sFecha) & ", "
	End If
	
	sFechaL = sFechaL & Day(sFecha) & " de " & sMesLargo(Month(sFecha)) & " de " & Year(sFecha)
	
	sFechaLarga = sFechaL
	
End Function


'------------------------------------------------------------------------------------
' Nombre: sFechaLarga2
' Descripción: convierte una fecha al formato largo que antepone la ciudad
' Fecha: 26/05/2005
' Autor: Departamento de Desarrollo - Tecnología (JPP)
' Parámetros: 
'			sFecha -> fecha 
'			bDenDiaSemana -> booleano que indica si se quiere que devuelva también la
'							 denominación del día de la semana
' Retorno: fecha en formato largo (opcional la denominación del día de la semana)
'------------------------------------------------------------------------------------
Function sFechaLarga2(sFecha, bDenDiaSemana)

	sFechaLarga2 = "Málaga, " & sFechaLarga(sFecha, bDenDiaSemana)
	
End Function


'------------------------------------------------------------------------------------
' Nombre: sDiaSemana
' Descripción: dada una fecha devuelve la denominación del día de la semana
' Fecha: 26/05/2005
' Autor: Departamento de Desarrollo - Tecnología (JPP)
' Parámetros: 
'			sFecha -> fecha 
' Retorno: denominación del día de la semana
'------------------------------------------------------------------------------------
Function sDiaSemana(sFecha)

	sDia = WeekDay(sFecha,vbMonday)

	If sDia="1" Then
		sDiaSemana = "Lunes"
	ElseIf sDia="2" Then
		sDiaSemana = "Martes"
	ElseIf sDia="3" Then
		sDiaSemana = "Miércoles"
	ElseIf sDia="4" Then
		sDiaSemana = "Jueves"
	ElseIf sDia="5" Then
		sDiaSemana = "Viernes"
	ElseIf sDia="6" Then
		sDiaSemana = "Sábado"
	ElseIf sDia="7" Then
		sDiaSemana = "Domingo"
	End If

End Function


'------------------------------------------------------------------------------------
' Nombre: sMesLargo
' Descripción: dada una fecha devuelve el mes en formato largo
' Fecha: 26/05/2005
' Autor: Departamento de Desarrollo - Tecnología (JPP)
' Parámetros: 
'			sMesNum -> nº del mes
' Retorno: mes en formato largo
'------------------------------------------------------------------------------------
Function sMesLargo(sMesNum)

	Dim sMesTexto
	
	If sMesNum="1" Then
		sMesTexto = "Enero"
	ElseIf sMesNum="2" Then
		sMesTexto = "Febrero"
	ElseIf sMesNum="3" Then
		sMesTexto = "Marzo"
	ElseIf sMesNum="4" Then
		sMesTexto = "Abril"
	ElseIf sMesNum="5" Then
		sMesTexto = "Mayo"
	ElseIf sMesNum="6" Then
		sMesTexto = "Junio"
	ElseIf sMesNum="7" Then
		sMesTexto = "Julio"
	ElseIf sMesNum="8" Then
		sMesTexto = "Agosto"
	ElseIf sMesNum="9" Then
		sMesTexto = "Septiembre"
	ElseIf sMesNum="10" Then
		sMesTexto = "Octubre"
	ElseIf sMesNum="11" Then
		sMesTexto = "Noviembre"
	ElseIf sMesNum="12" Then
		sMesTexto = "Diciembre"
	End If

	sMesLargo = sMesTexto
	
End Function